# SPDX-License-Identifier: GPL-3.0-or-later
# swat3port build: C11, CMake + Ninja, family warn level.
# The src/ tree mirrors ARCHITECTURE.md 1:1 — one static lib per component.
cmake_minimum_required(VERSION 3.20)
project(swat3port VERSION 0.1.0 LANGUAGES C)

set(CMAKE_C_STANDARD 11)
set(CMAKE_C_STANDARD_REQUIRED ON)
set(CMAKE_C_EXTENSIONS OFF)

option(SWAT3_SANITIZE "ASan+UBSan" OFF)

if(CMAKE_C_COMPILER_ID MATCHES "GNU|Clang")
  add_compile_options(-Wall -Wextra -Wpedantic)
  if(SWAT3_SANITIZE)
    add_compile_options(-fsanitize=address,undefined -fno-omit-frame-pointer)
    add_link_options(-fsanitize=address,undefined)
  endif()
endif()

find_package(PkgConfig REQUIRED)
pkg_check_modules(SDL2 REQUIRED IMPORTED_TARGET sdl2)

set(SWAT3_COMPONENTS core vfs fmt render sim ai sa ui input net platform)

foreach(comp IN LISTS SWAT3_COMPONENTS)
  add_library(swat3_${comp} STATIC src/${comp}/${comp}.c)
  target_include_directories(swat3_${comp} PUBLIC src)
endforeach()

target_sources(swat3_core PRIVATE
  src/core/log.c src/core/settings.c src/core/loop.c src/core/replay.c)
target_link_libraries(swat3_vfs PUBLIC swat3_core)
target_link_libraries(swat3_fmt PUBLIC m)
target_link_libraries(swat3_platform PUBLIC PkgConfig::SDL2 swat3_core)

target_sources(swat3_render PRIVATE
  src/render/scene.c src/render/gles2.c src/render/soft.c src/render/raster3d.c)
target_link_libraries(swat3_render PUBLIC swat3_fmt swat3_vfs m
  PRIVATE PkgConfig::SDL2 swat3_core)

target_link_libraries(swat3_sa PUBLIC swat3_fmt m)
target_link_libraries(swat3_sim PUBLIC swat3_sa swat3_ai swat3_fmt swat3_vfs swat3_input swat3_core m)
target_link_libraries(swat3_ai PUBLIC swat3_sa swat3_fmt m)
target_link_libraries(swat3_ui PUBLIC swat3_sim swat3_net swat3_render swat3_core m)
target_link_libraries(swat3_net PUBLIC swat3_input swat3_core)

target_sources(swat3_input PRIVATE src/input/assist.c)
target_link_libraries(swat3_input PRIVATE PkgConfig::SDL2 swat3_core m)

add_executable(swat3port src/main.c)
target_link_libraries(swat3port PRIVATE
  swat3_ui swat3_sim swat3_ai swat3_sa swat3_net
  swat3_platform swat3_core swat3_render swat3_fmt swat3_vfs swat3_input m)

enable_testing()
add_subdirectory(tests)

add_custom_target(check-clean
  COMMAND /bin/sh ${CMAKE_SOURCE_DIR}/tools/check-clean.sh ${CMAKE_SOURCE_DIR}
  USES_TERMINAL)
add_custom_target(perf-check
  COMMAND ${CMAKE_CTEST_COMMAND} --test-dir ${CMAKE_BINARY_DIR} -L perf --output-on-failure
  USES_TERMINAL)
